@echo off

set cafProgramData=%ProgramData%/VMware/VMware CAF/pme
set inputDir=%cafProgramData%/data/input
set crtDir=%ProgramData%\VMware\VMware Tools\GuestProxyData\server
set copyCcafProgramData=%cafProgramData%

set cafProgramFiles=%cafProgramFiles:\=/%
set cafProgramData=%cafProgramData:\=/%

set persistDir=%cafProgramData%/data/input/persistence
set copyPersistDir=%copyCcafProgramData%\data\input\persistence

call:preConfigureListener
rem call:setListenerConfigured
echo | set /p=true
goto:end

:preConfigureListener
    md "%persistDir%/local"
    md "%persistDir%/protocol/amqpBroker_default"
    md "%persistDir%/protocol/amqpBroker_default/tlsCertCollection"
    md "%persistDir%/protocol/amqpBroker_default/tlsCipherCollection"
    md "%persistDir%/remote/remote_default"
    md "%persistDir%/remote/remote_default/cmsCertCollection"

    if not exist "%persistDir%/local/cert.pem" (
        copy /Y "%crtDir%\key.pem" "%copyPersistDir%\local\privateKey.pem"
        copy /Y "%crtDir%\cert.pem" "%copyPersistDir%\local\cert.pem"
    )

    if not exist "%persistDir%/protocol/amqpBroker_default/tlsCert.pem" (
        copy /Y "%crtDir%\cert.pem" "%copyPersistDir%\protocol\amqpBroker_default\tlsCert.pem"
        copy /Y "%crtDir%\cert.pem" "%copyPersistDir%\protocol\amqpBroker_default\tlsCertCollection\tlsCert0.pem"

        echo SRP-RSA-AES-128-CBC-SHA > "%persistDir%/protocol/amqpBroker_default/tlsCipherCollection/tlsCipher0.txt"
        echo amqpBroker_default > "%persistDir%/protocol/amqpBroker_default/protocolName.txt"
        echo TLSv1.2 > "%persistDir%/protocol/amqpBroker_default/tlsProtocol.txt"
    )

    if not exist "%persistDir%/remote/remote_default/cmsCert.pem" (
        copy /Y "%crtDir%\cert.pem" "%copyPersistDir%\remote\remote_default\cmsCert.pem"
        copy /Y "%crtDir%\cert.pem" "%copyPersistDir%\remote\remote_default\cmsCertCollection\cmsCert0.pem"

        echo remote_default > "%persistDir%/remote/remote_default/remoteId.txt"
        echo amqpBroker_default > "%persistDir%/remote/remote_default/protocolName.txt"
        echo des-ede3-cbc > "%persistDir%/remote/remote_default/cmsCipherName.txt"
    )

   exit /b 0

:setListenerConfigured
    echo Automatic > "%inputDir%/monitor/listenerConfiguredStage1.txt"
    echo PreConfigured > "%inputDir%/monitor/listenerPreConfigured.txt"
   exit /b 0


:end